Μερικές Διαφορικές Εξισώσεις

Εξίσωση κύματος ($\partial_{tt} u-c^2 \nabla^2 u=0$)

Γενική λύση

Clear["Global`*"]
PDE = D[u[x, t], {t, 2}] - c^2 D[u[x, t], {x, 2}] == 0
(*arb1, arb2 αυθαίρετες*)
uSol[x_, t_] := arb1[x + c t] + arb2[x - c t]

u^{(0,2)}(x,t)-(c^{2}) u^{(2,0)}(x,t)=0

Χωρισμός μεταβλητών (πεπερασμένο χωρίο)

Στήσιμο ΜΔΕ.

Clear["Global`*"]
PDE = D[u[x, t], {t, 2}] - c^2 D[u[x, t], {x, 2}] == 0;
u[x, t] = X[x]*T[t]
PDE = D[u[x, t], {t, 2}] - c^2 D[u[x, t], {x, 2}] == 0

\(T[t] X[x]\)

X[x] (T'')[t]-(c^{2}) T[t] (X'')[x]=0

Αρχικές συνθήκες

init1 = u[x, 0] == f[x]
init2 = Derivative[0, 1][u][x, 0] == g[x]

\[u(x,0)=f(x)\]

u^{(0,1)}(x,0)=g(x)

Συνωριακές συνθήκες

bound1 = u[0, t] == 0
bound2 = u[L, t] == 0

\[u(0,t)=0\]

\[u(L,t)=0\]

PDE[[1]]/(c^2 X[x] T[t]) // Apart

\frac{(T'')[t]}{(c^{2}) T[t]}-\frac{(X'')[x]}{X[x]}

ODEt = T''[t]/(c^2 T[t]) == λ
ODEx = X''[x]/X[x] == λ

\frac{(T'')[t]}{(c^{2}) T[t]}=\lambda

\frac{(X'')[x]}{X[x]}=\lambda

Εξετάζουμε πρώτα τις προς απόρριψιν περιπτώσεις $λ\geq0$. Από τις u(0,t)==0 και u(L,t)==0 συνάγουμε ότι X(0)T(t)==0==X(L)T(t). Επομένως X(0)==0==X(L), προκειμένου να αποφύγουμε τη μηδενική λύση.

Assuming[λ > 0, DSolve[ODEx, X[x], x]]
Assuming[λ > 0, DSolve[{ODEx, X[0] == 0, X[L] == 0}, X[x], x]]

{{X[x]\to (E^{x (\sqrt{\lambda })}) C_{1}+(E^{-x (\sqrt{\lambda })}) C_{2}}}

{{X[x]\to 0}}

Στην περίπτωση που λ=0 έχουμε:

ODEx = X''[x] == 0

\[(X'')[x]=0\]

DSolve[{ODEx}, X[x], x]
DSolve[{ODEx, X[0] == 0, X[L] == 0}, X[x], x]

{{X[x]\to C_{1}+x C_{2}}}

{{X[x]\to \begin{cases}x C_{1} & L=0 \\ 0 & True\end{cases}}}

Αποδείξαμε ότι λ<0, επομένως:

λ = -k^2
ODEx = X''[x] + k^2 X[x] == 0
DSolve[{ODEx}, X[x], x]
DSolve[{ODEx, X[0] == 0, X[L] == 0}, X[x], x]

-(k^{2})

(k^{2}) X[x]+(X'')[x]=0

{{X[x]\to C_{1} \cos(k x)+C_{2} \sin(k x)}}

{{X[x]\to \begin{cases}C_{1} \sin((\sqrt{k^{2}}) x) & n \in Integers\mathbin{\&\&}n >=1\mathbin{\&\&}k^{2}=\frac{({n }^{2}) ({\pi }^{2})}{L^{2}}\mathbin{\&\&}L>0 \\ 0 & True\end{cases}}}

Έχουμε τις ιδιοτιμές:

k = (m Pi)/L

\frac{m \pi }{L}

Άρα:

DSolve[{ODEx, X[0] == 0, X[L] == 0}, X[x], x]
DSolve[ODEt, T[t], t]

{{X[x]\to \begin{cases}C_{1} \sin(\frac{m \pi x}{L}) & n \in Integers\mathbin{\&\&}(m=2 n \mathbin{|}m=\frac{\pi +2 n \pi }{\pi }) \\ 0 & True\end{cases}}}

{{T[t]\to C_{1} \cos(\frac{c m \pi t}{L})+C_{2} \sin(\frac{c m \pi t}{L})}}

Έχουμε ότι η $u_m(x,t)=\sin(\dfrac{m \pi x}{L})(a_m \cos(\dfrac{c m \pi t}{L})+b_m\sin(\dfrac{c m \pi t}{L}))$ ικανοποιεί τη Μ.Δ.Ε. και τις συνοριακές συνθήκες. Το ίδιο συμβαίνει και με κάθε γραμμικό συνδυασμό τους. Θα βρούμε ποιος γραμμικός συνδυασμός επαληθεύει και τις αρχικές συνθήκες. Θέλουμε, δηλαδή:

$\sum_{m=1}^{\infty}u_m(x,0)=f (x)\Leftrightarrow \sum_{m=1}^{\infty}a_m \sin(\dfrac{m \pi x}{L})=f(x)$
${\sum_{m=1}^{\infty}\partial_t u_m(x,0)=g(x)}\Leftrightarrow {\sum_{m=1}^{\infty} {\dfrac{c m b_m \pi }{L}}\sin(\dfrac{m \pi x}{L})=g(x)}$

Οι συντελεστές $a_m$ και $b_m$ θα βρεθούν πολλαπλασιάζοντας εσωτερικά με $\sin(m x)$ και τα δύο μέλη των ισοτήτων. Λαμβάνοντας υπ' όψιν την ορθογωνιότητα των ημιτόνων έχουμε:

a[m_] := Assuming[Element[m, Integers], 
  Integrate[f[x] Sin[(m π x)/L], {x, 0, L}]/
  Integrate[(Sin[(m π x)/L])^2, {x, 0, L}]]
a[m]

\frac{2 (\int_{0}^{L} f(x) \sin(\frac{m \pi x}{L}) \,dx)}{L}

b[m_] := Assuming[Element[m, Integers], 
  Integrate[g[x] Sin[(m π x)/L], {x, 0, L}]/((c m Pi)/
   L Integrate[(Sin[(m π x)/L])^2, {x, 0, L}])]
b[m]

\frac{2 (\int_{0}^{L} g(x) \sin(\frac{m \pi x}{L}) \,dx)}{c m \pi }

un[x_, t_, m_] := 
 Sin[(m π x)/L] (a[m] Cos[(c m π t)/L] + b[m] Sin[(c m π t)/L])
uApprox[x_, t_, n0_] := Sum[un[x, t, m], {m, 1, n0}]
uApprox[x, t, 4]

(\frac{2 \cos(\frac{c \pi t}{L}) (\int_{0}^{L} f(x) \sin(\frac{\pi x}{L}) \,dx)}{L}+\frac{2 (\int_{0}^{L} g(x) \sin(\frac{\pi x}{L}) \,dx) \sin(\frac{c \pi t}{L})}{c \pi }) \sin(\frac{\pi x}{L})+(\frac{2 \cos(\frac{2 c \pi t}{L}) (\int_{0}^{L} f(x) \sin(\frac{2 \pi x}{L}) \,dx)}{L}+\frac{(\int_{0}^{L} g(x) \sin(\frac{2 \pi x}{L}) \,dx) \sin(\frac{2 c \pi t}{L})}{c \pi }) \sin(\frac{2 \pi x}{L})+(\frac{2 \cos(\frac{3 c \pi t}{L}) (\int_{0}^{L} f(x) \sin(\frac{3 \pi x}{L}) \,dx)}{L}+\frac{2 (\int_{0}^{L} g(x) \sin(\frac{3 \pi x}{L}) \,dx) \sin(\frac{3 c \pi t}{L})}{3 c \pi }) \sin(\frac{3 \pi x}{L})+(\frac{2 \cos(\frac{4 c \pi t}{L}) (\int_{0}^{L} f(x) \sin(\frac{4 \pi x}{L}) \,dx)}{L}+\frac{(\int_{0}^{L} g(x) \sin(\frac{4 \pi x}{L}) \,dx) \sin(\frac{4 c \pi t}{L})}{2 c \pi }) \sin(\frac{4 \pi x}{L})

Ας εξειδικεύσουμε την κατάσταση, για να δούμε τι πετύχαμε.

c = 4;
L = 2 Pi;
f[x_] := x^2
g[x_] := 2 x - 1

uApprox[x, t, 6]

(\frac{8 (-4+{\pi }^{2}) \cos(2 t)}{\pi }+\frac{(-4+8 \pi ) \sin(2 t)}{2 \pi }) \sin(\frac{x}{2})+(-4 \pi \cos(4 t)-\sin(4 t)) \sin(x)+(\frac{8 (-4+9 ({\pi }^{2})) \cos(6 t)}{27 \pi }+\frac{2 (-1+2 \pi ) \sin(6 t)}{9 \pi }) \sin(\frac{3 x}{2})+(-2 \pi \cos(8 t)-(\frac{1}{4}) \sin(8 t)) \sin(2 x)+(\frac{8 (-4+25 ({\pi }^{2})) \cos(10 t)}{125 \pi }+\frac{2 (-1+2 \pi ) \sin(10 t)}{25 \pi }) \sin(\frac{5 x}{2})+(-\frac{4}{3} \pi \cos(12 t)-(\frac{1}{9}) \sin(12 t)) \sin(3 x)

Table[Plot3D[Evaluate[uApprox[x, t, n0]], {x, 0, L}, {t, 0, 10}], {n0,   1, 6}]

Plot3D[Evaluate[uApprox[x, t, 30]], {x, 0, L}, {t, 0, 10},  AxesLabel -> {"x","t"}]